  
  [1X10 Examples[0X
  
  To  actually  run an orbit enumeration by suborbits, we have to collect some
  insight  into  the  structure  of the group under consideration and into its
  representation  theory.  In  general, preparing the input data is more of an
  art than a science. The mathematical details are described in [MNW07].
  
  In   Section   [14X10.1[0m  we  present  a  small  example  of  the  usage  of  the
  orbit-by-suborbit machinery. We use the sporadic simple Mathieu group M_{11}
  acting projectively on its irreducible module of dimension 24 over the field
  with 3 elements.
  
  In   Section   [14X10.2[0m   we  present  another  example  of  the  usage  of  the
  orbit-by-suborbit programs. In this example we determine 35 of the 36 double
  coset  representatives  of  the  sporadic  simple Fischer group Fi_{23} with
  respect to its seventh maximal subgroup.
  
  In   Section  [14X10.3[0m  we  present  a  bigger  example  of  the  usage  of  the
  orbit-by-suborbit  machinery.  In  this  example  the  orbit  lengths of the
  sporadic  simple Conway group Co_{1} acting in in its irreducible projective
  representation   over  the  field  with  5  elements  in  dimension  24  are
  determined,  which  were previously unknown. These orbit lengths were needed
  to rule out a case in [Mal06].
  
  In  Section  [14X10.4[0m  we present as an extended worked example how to enumerate
  the  smallest non-trivial orbit of the sporadic simple Baby Monster group B.
  We  give a log of a [5XGAP[0m session with explanations in between, being intended
  to  illustrate  a few of the tools which are available in the [5Xorb[0m package as
  well as in related packages. Actually, the [5Xorb[0m package has also been applied
  to  two  much  larger  permutation actions of B, namely its action on its 2B
  involutions,  having  degree approx 1.2* 10^13, and its action on the cosets
  of  a maximal subgroup isomorphic to Fi_23, having degree approx 1.0* 10^15;
  for details see [M{\08] and [MNW07], respectively.
  
  Note  that for all this to work you have to acquire and install the packages
  [5XIO[0m,  [5Xcvec[0m,  and  [5Xatlasrep[0m,  and  for  Section [14X10.4[0m you additionally need the
  packages [5Xchop[0m and [5Xgenss[0m.
  
  
  [1X10.1 The Mathieu group M_{11} acting in dimension 24[0X
  
  The  example  in  this  section  is  very  small  but  our intention is that
  everything can still be analysed and looked at more or less by hand. We want
  to  enumerate  orbits of the Mathieu group M_{11} acting projectively on its
  irreducible  module  of dimension 24 over the field with 3 elements. All the
  files for this example are located in the [11Xexamples/m11PF3d24[0m subdirectory of
  the [5Xorb[0m package. Then you simply run the example in the following way:
  
  [4X---------------------------  Example  ----------------------------[0X
    [4Xgap> ReadPackage("orb","examples/m11PF3d24/M11OrbitOnPF3d24.g");[0X
    [4X...[0X
    [4Xgap> o := OrbitBySuborbit(setup,v,3,3,2,100);[0X
    [4X...[0X
    [4X#I  OrbitBySuborbit found 100% of a U3-orbit of size 7 920[0X
    [4X...[0X
  [4X------------------------------------------------------------------[0X
  
  Everything  works  instantly as it would have without the orbit-by-suborbits
  method.  (Depending  on  whether  the  matrix and permutation generators for
  M_{11} are already stored locally, some time might be needed to fetch them.)
  The  details  of  this computation can be directly read off from the code in
  the file [11XM11OrbitOnPF3d24.g[0m:
  
  [4X---------------------------  Example  ----------------------------[0X
    [4XLoadPackage("orb");[0X
    [4XLoadPackage("io");[0X
    [4XLoadPackage("cvec");[0X
    [4XLoadPackage("atlasrep");[0X
    [4X[0X
    [4XSetInfoLevel(InfoOrb,2);[0X
    [4Xpgens := AtlasGenerators("M11",1).generators;[0X
    [4X[0X
    [4Xgens := AtlasGenerators("M11",14).generators;[0X
    [4Xcgens := List(gens,CMat);[0X
    [4Xbasech := CVEC_ReadMatFromFile(Filename(DirectoriesPackageLibrary("orb",""),[0X
    [4X          "examples/m11PF3d24/m11basech.cmat"));[0X
    [4Xbasechi := basech^-1;[0X
    [4Xcgens := List(cgens,x->basech*x*basechi);[0X
    [4X[0X
    [4XReadPackage("orb","examples/m11PF3d24/m11slps.g");[0X
    [4Xpgu2 := ResultOfStraightLineProgram(s2,pgens);[0X
    [4Xpgu1 := ResultOfStraightLineProgram(s1,pgu2);[0X
    [4Xcu2 := ResultOfStraightLineProgram(s2,cgens);[0X
    [4Xcu1 := ResultOfStraightLineProgram(s1,cu2);[0X
    [4X[0X
    [4Xsetup := OrbitBySuborbitBootstrapForLines([0X
    [4X         [cu1,cu2,cgens],[pgu1,pgu2,pgens],[20,720,7920],[5,11],rec());[0X
    [4Xsetup!.stabchainrandom := 900;[0X
    [4X[0X
    [4Xv := ZeroMutable(cgens[1][1]);[0X
    [4XRandomize(v);[0X
    [4XORB_NormalizeVector(v); [0X
    [4X[0X
    [4XPrint("Now do\n  o := OrbitBySuborbit(setup,v,3,3,2,100);\n");[0X
  [4X------------------------------------------------------------------[0X
  
  We  are  using two helper subgroups U_1 < U_2 < M_11, where U_2cong A_2.2 is
  the largest maximal subgroup of M_11, having order 720, and U_2cong 5:4 is a
  maximal  subgroup  of U_2 of order 20, see [CCNPW85] or the [5XCTblLib[0m package.
  The quotient spaces we use for the helper subgroups have dimensions 5 and 11
  respectively.  Straight  line  programs  to compute generators of the helper
  subgroups in terms of the given generators of M_11, and an appropriate basis
  exhibiting  the quotients, have already been computed, and are stored in the
  files  [11Xm11slps.g[0m  and [11Xm11basech.cmat[0m, respectively. (In Section [14X10.4[0m we show
  in  detail  how  such straight line programs and suitable bases can be found
  using   the   tools   available   in   in  the  [5Xorb[0m  package.)  The  command
  [11XOrbitBySuborbitBootstrapForLines[0m   invokes   the   precomputation,   and  in
  particular says that we want to use projective action.
  
  
  [1X10.2 The Fischer group Fi_{23} acting in dimension 1494[0X
  
  The  example  in this section shows how to compute 35 of the 36 double coset
  representatives of the Fischer group Fi_{23} with respect to its the seventh
  maximal   subgroup   Hcong  3_+^1+8.2_-^1+6.3_+^1+2.2S_4,  which  has  order
  3,265,173,504approx  3.2*  10^9  and index [Fi_{23}: H]=1,252,451,200 approx
  1.3  *  10^9,  see  [CCNPW85] or the [5XCTblLib[0m package. All the files for this
  example  are located in the [11Xexamples/fi23m7[0m subdirectory of the [5Xorb[0m package.
  You simply run the example in the following way:
  
  [4X---------------------------  Example  ----------------------------[0X
    [4Xgap> ReadPackage("orb","examples/fi23m7/GOrbitByKOrbitsPrepare.g");[0X
    [4X...[0X
    [4Xgap> ReadPackage("orb","examples/fi23m7/GOrbitByKOrbitsSearch35.g");[0X
    [4X...[0X
  [4X------------------------------------------------------------------[0X
  
  We  will  not  go  into the details of the computation here, but they can be
  read off directly from the code in the files in that directory. In the first
  part,  run  by  the  file [11XGOrbitByKOrbitsPrepare.g[0m, we prepare the necessary
  input  data,  by  using similar techniques as described at length in Section
  [14X10.4[0m.  (Actually,  this example has been dealt with before the advent of the
  packages  [5Xchop[0m  and  [5Xgenss[0m,  hence  we  are  using  appropriate private code
  instead.)  We  are using two helper subgroups U_1 < U_2 < H < Fi_{23}, being
  3-subgroups  of  H  of order 81 and 6561, respectively. The 1494-dimensional
  irreducible  representation  of  Fi_{23}  over  the  field  with  2 elements
  contains  a  vector  that  is  fixed  by  H,  such  that  the  action on its
  Fi_{23}-orbit is isomorphic to the action on the cosets of H.
  
  The  second  part,  in  the  file  [11XGOrbitByKOrbitsSearch35.g[0m,  is the actual
  enumeration of H-orbits:
  
  [4X---------------------------  Example  ----------------------------[0X
    [4Xsetup := OrbitBySuborbitBootstrapForVectors([0X
    [4X         [cu1gens,cu2gens,cngens],[u1gensp,u2gensp,ngensp],[0X
    [4X         [81,6561,3265173504],[10,30],rec());[0X
    [4Xobsol := InitOrbitBySuborbitList(setup,40);[0X
    [4Xl := Orb(cggens,v,OnRight,rec(schreier := true));[0X
    [4XEnumerate(l,100000);[0X
    [4XOrbitsFromSeedsToOrbitList(obsol,l);[0X
    [4Xorigseeds := List(obsol,OrigSeed); [0X
    [4Xpositions :=  List(origseeds,x->Position(l,x));[0X
    [4Xwords := List(positions,x->TraceSchreierTreeForward(l,x));[0X
  [4X------------------------------------------------------------------[0X
  
  Note   that   this  computation  finds  only  35  of  the  36  double  coset
  representatives. The last corresponds to a very short suborbit which is very
  difficult  to  find.  Knowing  the  number  of  missing points, we guess the
  stabiliser in H of a missing representative, and find the latter amongst the
  fixed points of the stabiliser. We can then choose the one which lies in the
  G-orbit we have nearly enumerated above.
  
  These  double  coset  representatives were needed to determine the 2-modular
  character table of Fi_{23}. Details of this can be found in [HNN06].
  
  
  [1X10.3 The Conway group Co_1 acting in dimension 24[0X
  
  The example in this section shows how to compute all suborbit lengths of the
  Conway  group  Co_1,  in  its  irreducible  projective action on a module of
  dimension  24 over the field with 5 elements. All the files for this example
  are  located  in the [11Xexamples/co1F5d24[0m subdirectory of the [5Xorb[0m package. Then
  you simply run the example in the following way:
  
  [4X---------------------------  Example  ----------------------------[0X
    [4Xgap> ReadPackage("orb","examples/co1F5d24/Co1OrbitOnPF5d24.g");[0X
    [4X...[0X
    [4Xgap> ReadPackage("orb","examples/co1F5d24/Co1OrbitOnPF5d24.findall.g");[0X
    [4X...[0X
  [4X------------------------------------------------------------------[0X
  
  We  will  not go into the details of the first part of the computation here,
  as  they  are  very  similar to those reproduced in Section [14X10.1[0m, and can be
  directly read off from the code in the file [11XCo1OrbitOnPF5d24.g[0m: We are using
  three  helper  subgroups  U_1  <  U_2  <  U_3  <  Co_1, where Co_1 has order
  4,157,776,806,543,360,000approx  4.2*  10^18,  see  [CCNPW85] or the [5XCTblLib[0m
  package,  and  where U_3cong 2_+^1+8.O_8(2) is the fifth maximal subgroup of
  Co_1,  having  order  89,181,388,800approx  8.9* 10^10, while U_2cong [2^8]:
  S_6(2)  is  a  maximal subgroup of U_3 of order 371,589,120approx 3.7* 10^8,
  and   U_1cong  2^6:  L_3(2)  is  a  maximal  subgroup  of  S_6(2)  of  order
  10,752approx  1.1*  10^4.  The  projective action comes from the irreducible
  24-dimensional  linear  representation  of  the  Schur cover 2.Co_1 of Co_1,
  which  by [Jan05] is the smallest faithful representation of 2.Co_1 over the
  field  GF(5),  and  the quotient spaces we use for the helper subgroups have
  dimensions 8, 8 and 16 respectively.
  
  The details of the second part can be directly read off from the code in the
  file [11XCo1OrbitOnPF5d24.findall.g[0m:
  
  [4X---------------------------  Example  ----------------------------[0X
    [4Xoo := InitOrbitBySuborbitList(setup,80);[0X
    [4Xl := MakeRandomLines(v,1000);[0X
    [4XOrbitsFromSeedsToOrbitList(oo,l);[0X
    [4Xintervecs := CVEC_ReadMatFromFile(Filename(DirectoriesPackageLibrary("orb",""),[0X
    [4X             "examples/co1F5d24/co1interestingvecs.cmat"));[0X
    [4XOrbitsFromSeedsToOrbitList(oo,intervecs);[0X
    [4XLength(oo!.obsos);[0X
    [4XSum(oo!.obsos,Size);[0X
    [4X(5^24-1)/(5-1);[0X
  [4X------------------------------------------------------------------[0X
  
  Note that this example needs about 2GB of main memory on a 32bit machine and
  probably  nearly  4GB  on  a  64bit machine. However, the orbit lengths were
  previously  unknown  before  they were computed with this program. The orbit
  lengths were needed to rule out a case in [Mal06].
  
  
  [1X10.4 The Baby Monster B acting on its 2A involutions[0X
  
  The  example in this section shows how to enumerate the smallest non-trivial
  orbit  of  the  Baby  Monster  group  B.  All the files for this example are
  located  in  the [11Xexamples/bmF2d4370[0m subdirectory of the [5Xorb[0m package. You may
  simply run the example in the following way:
  
  [4X---------------------------  Example  ----------------------------[0X
    [4Xgap> ReadPackage("orb","examples/bmF2d4370/BMOrbitOnF2d4370partI.g");[0X
    [4X...[0X
    [4Xgap> ReadPackage("orb","examples/bmF2d4370/BMOrbitOnF2d4370partII.g");[0X
    [4X... [0X
  [4X------------------------------------------------------------------[0X
  
  In  the sequel we comment in detail on how the necessary input data actually
  is prepared. We begin by loading the packages we are going to use.
  
  [4X---------------------------  Example  ----------------------------[0X
    [4Xgap> LoadPackage("orb");[0X
    [4X...[0X
    [4Xgap> LoadPackage("io");[0X
    [4X...[0X
    [4Xgap> LoadPackage("cvec");[0X
    [4X...[0X
    [4Xgap> LoadPackage("atlasrep");[0X
    [4X...[0X
    [4Xgap> LoadPackage("chop");[0X
    [4X...[0X
    [4Xgap> LoadPackage("genss");[0X
    [4X...  [0X
  [4X------------------------------------------------------------------[0X
  
  The  one-point stabilisers associated to the smallest non-trivial orbit of B
  are  its  largest  maximal  subgroups  E  cong  2.^2E_6(2).2,  which are the
  centralisers  of  its  2A involutions. Here E is a bicyclic extension of the
  twisted  Lie type group ^2E_6(2), and has index [B: E]=13,571,955,000 approx
  1.4 * 10^10, see [CCNPW85] or the [5XCTblLib[0m package.
  
  We  first  try to find a matrix representation of B such that the B-orbit we
  look for is realised as a set of vectors in the underlying vector space. The
  smallest  faithful  representation  of  B  over  the field GF(2), by [Jan05]
  having  dimension  4370,  springs  to  mind.  Explicit  matrices in terms of
  standard  generators  in  the sense of [Wil96] are available in [ATLAS], and
  are  accessibe through the [5Xatlasrep[0m package. Moreover, we find generators of
  E  by  applying  a  straight  line  program,  also available in the [5Xatlasrep[0m
  package, expressing generators of E in terms of the generators of B.
  
  [4X---------------------------  Example  ----------------------------[0X
    [4Xgap> gens := AtlasGenerators("B",1).generators;[0X
    [4X[ <an immutable 4370x4370 matrix over GF2>, [0X
    [4X  <an immutable 4370x4370 matrix over GF2> ][0X
    [4Xgap> bgens := List(gens,CMat);[0X
    [4X[ <cmat 4370x4370 over GF(2,1)>, <cmat 4370x4370 over GF(2,1)> ] [0X
    [4Xgap> slpbtoe := AtlasStraightLineProgram("B",1).program;;[0X
    [4Xgap> egens := ResultOfStraightLineProgram(slpbtoe,bgens);[0X
    [4X[ <cmat 4370x4370 over GF(2,1)>, <cmat 4370x4370 over GF(2,1)> ] [0X
  [4X------------------------------------------------------------------[0X
  
  We  look for a non-zero vector being fixed by both generators of E. It turns
  out  that the latter have a common fixed space of dimension 1. Then, since E
  is  a maximal subgroup, the stabiliser in B of the non-zero vector v in that
  fixed space coincides with E.
  
  [4X---------------------------  Example  ----------------------------[0X
    [4Xgap> x := egens[1]-egens[1]^0;;[0X
    [4Xgap> nsx := NullspaceMat(x);[0X
    [4X<immutable cmat 2202x4370 over GF(2,1)>[0X
    [4Xgap> y := nsx * (egens[2]-egens[2]^0);;[0X
    [4Xgap> nsy := NullspaceMat(y);[0X
    [4X<immutable cmat 1x2202 over GF(2,1)>[0X
    [4Xgap> v := nsy[1]*nsx;[0X
    [4X<immutable cvec over GF(2,1) of length 4370> [0X
  [4X------------------------------------------------------------------[0X
  
  Storing  eight  elements  of  GF(2) into 1 byte, to store a vector of length
  4370  needs  547  bytes plus some organisational overhead resulting in about
  580  bytes, hence to store the full B-orbit of v we need 580 * [B: E] approx
  7.9 * 10^12 bytes. Hence we try to find helper subgroups suitable to achieve
  a  saving  factor  of  approx  10^4, i. e. allowing to store only one out of
  approx  10^4  vectors.  To  this  end,  we look for a pair U_1<U_2 of helper
  subgroups  such  that  |U_2|  approx  10^5,  where we take into account that
  typically  the  overall  saving factor achieved is somewhat smaller than the
  order of the largest helper subgroup.
  
  By [CCNPW85], and a few computations with subgroup fusions using the [5XCTblLib[0m
  package,  the  derived subgroup E' cong 2.^2E_6(2) of E turns out to possess
  maximal  subgroups  2  x Fi_{22} and 2.Fi_{22}, where Fi_{22} denotes one of
  the sporadic simple Fischer groups, and where the former constitute a unique
  conjugacy  class  with  associated  normalizers in E of shape 2 x Fi_{22}.2,
  while the latter consist of two conjugacy classes being self-normalising and
  interchanged by E.
  
  Now  Fi_{22} has a unique conjugacy class of maximal subgroups M_{12}, where
  the  latter denotes one of the sporadic simple Mathieu groups; the subgroups
  M_{12}  lift  to  a unique conjugacy class of subgroups M_{12} of 2.Fi_{22},
  which  turn  out to constitute a conjugacy class of subgroups of E different
  from  the  subgroups  M_{12}  being  contained  in  Fi_{22}. Anyway, we have
  |M_{12}|=95,040,  hence  U_2=M_{12}  seems  to  be  a good candidate for the
  larger  helper subgroup. In particular, there is a unique conjugacy class of
  maximal  subgroups  L_2(11)  of M_{12}, and since |L_2(11)|=660 and [M_{12}:
  L_2(11)]=144  letting  U_1=L_2(11)  seems  to  be  a  good candidate for the
  smaller helper subgroup. Recall that U_1 and U_2 are useful helper subgroups
  only  if  we  are  able  to  find suitable quotient modules allowing for the
  envisaged saving factor.
  
  To find U_1 and U_2, we first try to find a subgroup Fi_{22} or 2.Fi_{22} of
  E. We start a random search, aiming at finding standard generators of either
  Fi_{22} or 2.Fi_{22}, and we use [10XGeneratorsWithMemory[0m in order to be able to
  express  the generators found as words in the generators of E. To accelerate
  computations  we first construct a small representation of E; by [Jan05] the
  smallest  faithful  irreducible  representation  of  Fi_{22}  over GF(2) has
  dimension  78,  hence  we  cannot do better for E; note that the latter is a
  representation of overlineE:=E/Z(E) cong ^2E_6(2).2.
  
  [4X---------------------------  Example  ----------------------------[0X
    [4Xgap> SetInfoLevel(InfoChop,2);[0X
    [4Xgap> m := Module(egens);[0X
    [4X<module of dim. 4370 over GF(2)>[0X
    [4Xgap> r := Chop(m);[0X
    [4X...[0X
    [4Xrec( ischoprecord := true, [0X
    [4X  db := [ <abs. simple module of dim. 78 over GF(2)>, [0X
    [4X          <trivial module of dim. 1 over GF(2)>, [0X
    [4X          <abs. simple module of dim. 1702 over GF(2)>, [0X
    [4X          <abs. simple module of dim. 572 over GF(2)> ], [0X
    [4X  mult := [ 5, 4, 2, 1 ], acs := [ 1, 2, 3, 1, 4, 1, 1, 2, 2, 3, 1, 2 ], [0X
    [4X  module := <reducible module of dim. 4370 over GF(2)> )[0X
    [4Xgap> i := Position(List(r.db,Dimension),78);;[0X
    [4Xgap> egens78 := GeneratorsWithMemory(RepresentingMatrices(r.db[i]));[0X
    [4X[ <<immutable cmat 78x78 over GF(2,1)> with mem>, [0X
    [4X  <<immutable cmat 78x78 over GF(2,1)> with mem> ] [0X
  [4X------------------------------------------------------------------[0X
  
  By [ATLAS], standard generators a,b of Fi_{22} are given as follows: a is an
  element   of   the   2A   conjugacy   class  of  Fi_{22},  and  b,  ab,  and
  (ab)^4bab(abb)^2   have   order  13,  11,  and  12,  respectively;  standard
  generators  of  2.Fi_{22} are lifts of standard generators of Fi_{22} having
  the same order fingerprint. The 2A conjugacy class of Fi_{22} fuses into the
  2A  conjugacy  class of overlineE, where the latter is obtained as the 11-th
  power  of  the unique conjugacy class of elements of order 22, and overlineE
  has only one conjugacy class of elements of order 13.
  
  [4X---------------------------  Example  ----------------------------[0X
    [4Xgap> o := Orb(egens78,StripMemory(egens78[1])^0,OnRight,rec(schreier := true,[0X
    [4X>             lookingfor := function(o,x) return Order(x)=22; end));[0X
    [4X<open orbit, 1 points with Schreier tree looking for sth.>[0X
    [4Xgap> Enumerate(o);[0X
    [4X<open orbit, 393 points with Schreier tree looking for sth.>[0X
    [4Xgap> word := TraceSchreierTreeForward(o,PositionOfFound(o));[0X
    [4X[ 1, 2, 1, 2, 2, 1, 2, 2, 1, 2, 2 ][0X
    [4Xgap> g2a := Product(egens78{word})^11;[0X
    [4X<<immutable cmat 78x78 over GF(2,1)> with mem>[0X
    [4Xgap> o := Orb(egens78,StripMemory(egens78[1])^0,OnRight,rec(schreier := true,[0X
    [4X>             lookingfor := function(o,x) return Order(x)=13; end));[0X
    [4X<open orbit, 1 points with Schreier tree looking for sth.>[0X
    [4Xgap> Enumerate(o);[0X
    [4X<open orbit, 144 points with Schreier tree looking for sth.>[0X
    [4Xgap> word := TraceSchreierTreeForward(o,PositionOfFound(o));[0X
    [4X[ 1, 2, 1, 2, 1, 2, 1, 2, 2 ][0X
    [4Xgap> b := Product(egens78{word});[0X
    [4X<<immutable cmat 78x78 over GF(2,1)> with mem> [0X
  [4X------------------------------------------------------------------[0X
  
  We  search through the overlineE-conjugates of [10Xg2a[0m until we find a conjugate
  a  together with b fulfilling the defining conditions of standard generators
  of  Fi_{22},  and  moreover  fulfilling  the  relations  of  the  associated
  presentation of Fi_{22} available in [ATLAS].
  
  To  find  conjugates,  we  use  the product replacement algorithm to produce
  pseudo  random  elements of overlineE. Assuming a genuine random search, the
  success    probability   of   this   approach   is   as   follows:   Letting
  overlineE':=E'/Z(E')       cong       ^2E_6(2),       out       of       the
  |overlineE'|/|C_overlineE'}(g2a)|   conjugates   of   [10Xg2a[0m   there  are  |C_{
  overlineE' }(b)|/|C_{ overlineE' }(Fi_{22})| =|C_{ overlineE' }(b)| elements
  together  with  the  fixed  element b giving standard generators of Fi_{22}.
  Since  Fi_{22}  has two conjugacy classes of elements of order 13, and there
  are  three conjugacy classes of subgroups Fi_{22} of overlineE', the success
  probability   is   6   *   |C_{   overlineE'   }(g2a)|   *  |C_{  overlineE'
  }(b)|/|overlineE'| approx 2 * 10^-5.
  
  [4X---------------------------  Example  ----------------------------[0X
    [4Xgap> pr := ProductReplacer(egens78,rec(maxdepth := 150));[0X
    [4X<product replacer nrgens=2 slots=12 scramble=100 maxdepth=150 steps=0 (rattle)>[0X
    [4Xgap> i := 0;;[0X
    [4Xgap> repeat[0X
    [4X>      i := i + 1; [0X
    [4X>      x := Next(pr);[0X
    [4X>      a := g2a^x;[0X
    [4X>    until IsOne((a*b)^11) and IsOne(((a*b)^4*b*a*b*(a*b*b)^2)^12) and[0X
    [4X>      IsOne((a*b^2)^21) and IsOne(Comm(a,b)^3) and [0X
    [4X>      IsOne(Comm(a,b^2)^3) and IsOne(Comm(a,b^3)^3) and[0X
    [4X>      IsOne(Comm(a,b^4)^2) and IsOne(Comm(a,b^5)^3) and[0X
    [4X>      IsOne(Comm(a,b*a*b^2)^3) and IsOne(Comm(a,b^-1*a*b^-2)^2) and[0X
    [4X>      IsOne(Comm(a,b*a*b^5)^2) and IsOne(Comm(a,b^2*a*b^5)^2);[0X
    [4Xgap> i;[0X
    [4X53271 [0X
  [4X------------------------------------------------------------------[0X
  
  Note  that  the  initial state of the random number generator does influence
  this  randomised  result:  it may very well be that you see some other value
  for i.
  
  Due to a presentation being available we have proved that the elements found
  generate  a  subgroup  Fi_{22}. If we had not had a presentation at hand, we
  might  only  have  been  able  to  find  elements  fulfilling  the  defining
  conditions  of  standard  generators  of  Fi_{22},  but  still  generating a
  subgroup  of  another  isomorphism type. In that case, for further checks we
  can  use  the  following tools: We try to find a short orbit of vectors, and
  using a randomized Schreier-Sims algorithm gives a lower bound for the order
  of  the  group  seen.  However,  we can use the action on the orbit to get a
  homomorphism  into  a  permutation  group,  allowing to prove that the group
  generated indeed has Fi_{22} as a quotient.
  
  [4X---------------------------  Example  ----------------------------[0X
    [4Xgap> S := StabilizerChain(Group(a,b),rec(TryShortOrbit := 30,[0X
    [4X>                                        OrbitLengthLimit := 5000));[0X
    [4X...[0X
    [4X<stabchain size=64561751654400 orblen=3510 layer=1 SchreierDepth=8>[0X
    [4X <stabchain size=18393661440 orblen=2816 layer=2 SchreierDepth=7>[0X
    [4X  <stabchain size=6531840 orblen=1680 layer=3 SchreierDepth=7>[0X
    [4X   <stabchain size=3888 orblen=243 layer=4 SchreierDepth=5>[0X
    [4X    <stabchain size=16 orblen=16 layer=5 SchreierDepth=2>[0X
    [4Xgap> Size(S)=Size(CharacterTable("Fi22"));[0X
    [4Xtrue [0X
    [4Xgap> p := Group(ActionOnOrbit(S!.orb,[a,b]));;[0X
    [4Xgap> DisplayCompositionSeries(p);[0X
    [4XG (2 gens, size 64561751654400)[0X
    [4X | Fi(22)[0X
    [4X1 (0 gens, size 1) [0X
  [4X------------------------------------------------------------------[0X
  
  We now return to our original representation.
  
  [4X---------------------------  Example  ----------------------------[0X
    [4Xgap> SetInfoLevel(InfoSLP,2); [0X
    [4Xgap> slpetofi22 := SLPOfElms([a,b]);[0X
    [4X<straight line program>[0X
    [4Xgap> Length(LinesOfStraightLineProgram(slpetofi22));[0X
    [4X278[0X
    [4Xgap> SlotUsagePattern(slpetofi22);;[0X
    [4Xgap> fgens := ResultOfStraightLineProgram(slpetofi22,egens);[0X
    [4X...[0X
    [4X[ <cmat 4370x4370 over GF(2,1)>, <cmat 4370x4370 over GF(2,1)> ] [0X
    [4Xgap> a := fgens[1];;[0X
    [4Xgap> b := fgens[2];; [0X
    [4Xgap> IsOne(b^13);[0X
    [4Xtrue[0X
    [4Xgap> IsOne((a*b)^11);[0X
    [4Xtrue[0X
    [4Xgap> IsOne((a*b^2)^21);[0X
    [4Xtrue [0X
  [4X------------------------------------------------------------------[0X
  
  By  construction  the  group  generated  by a,b is Fi_{22} or 2 x Fi_{22} or
  2.Fi_{22}.  Note  that due to different seeds in the random number generator
  it is in fact possible at this stage that you have created a different group
  as displayed here! In our outcome, since a has even order, and both b and ab
  have odd order, we cannot possibly have 2 x Fi_{22}; and by the presentation
  of 2.Fi_{22} available in [ATLAS] the order of ab^2 being 21 implies that we
  cannot  possibly  have 2.Fi_{22} either. Hence we indeed have found standard
  generators  of  Fi_{22}.  If  we  had  hit  one  of the cases 2 x Fi_{22} or
  2.Fi_{22},  we could just continue the above search until we find a subgroup
  Fi_{22},  or  using  the  above order fingerprint we could easily modify the
  elements found to obtain standard generators of either Fi_{22} or 2.Fi_{22}.
  
  Now,  standard  generators  of U_2=M_{12} in terms of standard generators of
  Fi_{22},  and  generators  of U_1=L_2(11) in terms of standard generators of
  M_{12}  are  accessible in the [5Xatlasrep[0m package. Note that if we had found a
  subgroup  2.Fi_{22}  above,  since  M_{12} lifts to a subgroup 2 x M_{12} of
  2.Fi_{22}, it would again be easy to find standard generators of M_{12} from
  the generators of M_{12} or 2 x M_{12} respectively provided by the [5Xatlasrep[0m
  package.  Anyway,  the  next task is to find good quotient modules such that
  the  helper  subgroups  have  longish  orbits  on  vectors.  To this end, we
  restrict to M_{12} and compute the radical series of the restricted module.
  
  [4X---------------------------  Example  ----------------------------[0X
    [4Xgap> slpfi22tom12 := AtlasStraightLineProgram("Fi22",14).program;;[0X
    [4Xgap> slpm12tol211 := AtlasStraightLineProgram("M12",5).program;;[0X
    [4Xgap> mgens := ResultOfStraightLineProgram(slpfi22tom12,fgens);[0X
    [4X[ <cmat 4370x4370 over GF(2,1)>, <cmat 4370x4370 over GF(2,1)> ][0X
    [4Xgap> lgens := ResultOfStraightLineProgram(slpm12tol211,mgens);[0X
    [4X[ <cmat 4370x4370 over GF(2,1)>, <cmat 4370x4370 over GF(2,1)> ] [0X
    [4Xgap> m := Module(mgens);;[0X
    [4Xgap> r := Chop(m);;[0X
    [4X...[0X
    [4Xgap> rad := RadicalSeries(m,r.db);[0X
    [4X...[0X
    [4Xrec( [0X
    [4X  db := [ <abs. simple module of dim. 144 over GF(2)>, [0X
    [4X          <abs. simple module of dim. 44 over GF(2)>, [0X
    [4X          <simple module of dim. 32 over GF(2) splitting field degree 2>, [0X
    [4X          <abs. simple module of dim. 10 over GF(2)>, [0X
    [4X          <trivial module of dim. 1 over GF(2)> ],[0X
    [4X  module := <reducible module of dim. 4370 over GF(2)>,[0X
    [4X  basis := <immutable cmat 4370x4370 over GF(2,1)>,[0X
    [4X  ibasis := <immutable cmat 4370x4370 over GF(2,1)>,[0X
    [4X  cfposs := [ [ [ 1 .. 144 ], [ 145 .. 288 ], [ 289 .. 432 ], [ 433 .. 576 ],[0X
    [4X...[0X
    [4X  isotypes := [ [ 1, 1, 1, 1, 2, 2, 2, 2, 2, 2, 2, 2, 2, 2, 2, 2, 3, 3, 3, 3,[0X
    [4X                  3, 3, 3, 3, 3, 3, 5, 5, 5, 5, 5, 5, 5, 5, 5, 5, 5, 5 ],[0X
    [4X...[0X
    [4X  isradicalrecord := true ) [0X
  [4X------------------------------------------------------------------[0X
  
  We  observe  that there are faithful irreducible quotients of dimensions 10,
  32,  44,  and  144. Since we look for a quotient module such that M_{12} has
  many  regular  orbits  on  vectors,  we  ignore  the  irreducible  module of
  dimension 10. We consider the one of dimension 32.
  
  [4X---------------------------  Example  ----------------------------[0X
    [4Xgap> i := Position(List(rad.db,Dimension),32);;[0X
    [4Xgap> mgens32 := RepresentingMatrices(rad.db[i]);[0X
    [4X[ <immutable cmat 32x32 over GF(2,1)>, <immutable cmat 32x32 over GF(2,1)> ][0X
    [4Xgap> OrbitStatisticOnVectorSpace(mgens32,95040,30);[0X
    [4XFound length     95040, have now   24 orbits, average length: 93060 [0X
  [4X------------------------------------------------------------------[0X
  
  This  is  excellent  indeed.  Hence we pick a summand of dimension 32 in the
  first  radical  layer,  and  apply  the  associated  base  change to all the
  generators.
  
  [4X---------------------------  Example  ----------------------------[0X
    [4Xgap> bgens := List(bgens,x->rad.basis*x*rad.ibasis);;[0X
    [4Xgap> egens := List(egens,x->rad.basis*x*rad.ibasis);;[0X
    [4Xgap> fgens := List(fgens,x->rad.basis*x*rad.ibasis);;[0X
    [4Xgap> mgens := List(mgens,x->rad.basis*x*rad.ibasis);;[0X
    [4Xgap> lgens := List(lgens,x->rad.basis*x*rad.ibasis);;[0X
    [4Xgap> j := Position(rad.isotypes[1],i);;[0X
    [4Xgap> l := rad.cfposs[1][j];;[0X
    [4Xgap> Append(l,Difference([1..4370],l));[0X
    [4Xgap> bgens := List(bgens,x->ORB_PermuteBasisVectors(x,l));;[0X
    [4Xgap> egens := List(egens,x->ORB_PermuteBasisVectors(x,l));;[0X
    [4Xgap> fgens := List(fgens,x->ORB_PermuteBasisVectors(x,l));;[0X
    [4Xgap> mgens := List(mgens,x->ORB_PermuteBasisVectors(x,l));;[0X
    [4Xgap> lgens := List(lgens,x->ORB_PermuteBasisVectors(x,l));; [0X
  [4X------------------------------------------------------------------[0X
  
  We consider the irreducible quotient module of M_{12} of dimension 32, whose
  restriction  to  L_2(11)  turns  out  to  be  is semisimple. The irreducible
  quotients of dimension 10 are too small to have too many regular orbits, but
  the direct sum of two of them turns out to work fine.
  
  [4X---------------------------  Example  ----------------------------[0X
    [4Xgap> lgens32 := List(lgens,x->ExtractSubMatrix(x,[1..32],[1..32]));[0X
    [4X[ <cmat 32x32 over GF(2,1)>, <cmat 32x32 over GF(2,1)> ][0X
    [4Xgap> m := Module(lgens32);;[0X
    [4Xgap> r := Chop(m);[0X
    [4X...[0X
    [4Xgap> soc := SocleSeries(m,r.db);[0X
    [4X...[0X
    [4Xrec( issoclerecord := true,[0X
    [4X  db := [ <simple module of dim. 10 over GF(2) splitting field degree 2>,[0X
    [4X          <trivial module of dim. 1 over GF(2)>,[0X
    [4X          <abs. simple module of dim. 10 over GF(2)> ],[0X
    [4X  module := <reducible module of dim. 32 over GF(2)>,[0X
    [4X  basis := <cmat 32x32 over GF(2,1)>, ibasis := <cmat 32x32 over GF(2,1)>,[0X
    [4X  cfposs := [ [ [ 1 .. 10 ], [ 11 ], [ 12 ], [ 13 .. 22 ], [ 23 .. 32 ] ] ],[0X
    [4X  isotypes := [ [ 1, 2, 2, 3, 3 ] ] )[0X
    [4Xgap> i := Position(List(soc.db,x->[Dimension(x),DegreeOfSplittingField(x)]),[0X
    [4X>                                 [10,1]);;[0X
    [4Xgap> j := Position(soc.isotypes[1],i);;[0X
    [4Xgap> l := Concatenation(soc.cfposs[1]{[j,j+1]});;[0X
    [4Xgap> lgens32 := List(lgens32,x->soc.basis*x*soc.ibasis);[0X
    [4X[ <cmat 32x32 over GF(2,1)>, <cmat 32x32 over GF(2,1)> ][0X
    [4Xgap> lgens20 := List(lgens32,x->ExtractSubMatrix(x,l,l));[0X
    [4X[ <cmat 20x20 over GF(2,1)>, <cmat 20x20 over GF(2,1)> ][0X
    [4Xgap> OrbitStatisticOnVectorSpace(lgens20,660,30);[0X
    [4XFound length       660, have now 4401 orbits, average length: 598 [0X
  [4X------------------------------------------------------------------[0X
  
  We apply the appropriate base change to all the generators.
  
  [4X---------------------------  Example  ----------------------------[0X
    [4Xgap> t := ORB_EmbedBaseChangeTopLeft(soc.basis,4370);[0X
    [4X<cmat 4370x4370 over GF(2,1)>[0X
    [4Xgap> ti := ORB_EmbedBaseChangeTopLeft(soc.ibasis,4370);[0X
    [4X<cmat 4370x4370 over GF(2,1)>[0X
    [4Xgap> bgens := List(bgens,x->t*x*ti);;[0X
    [4Xgap> egens := List(egens,x->t*x*ti);;[0X
    [4Xgap> fgens := List(fgens,x->t*x*ti);;[0X
    [4Xgap> mgens := List(mgens,x->t*x*ti);;[0X
    [4Xgap> lgens := List(lgens,x->t*x*ti);; [0X
    [4Xgap> Append(l,Difference([1..4370],l));[0X
    [4Xgap> bgens := List(bgens,x->ORB_PermuteBasisVectors(x,l));;[0X
    [4Xgap> egens := List(egens,x->ORB_PermuteBasisVectors(x,l));;[0X
    [4Xgap> fgens := List(fgens,x->ORB_PermuteBasisVectors(x,l));;[0X
    [4Xgap> mgens := List(mgens,x->ORB_PermuteBasisVectors(x,l));;[0X
    [4Xgap> lgens := List(lgens,x->ORB_PermuteBasisVectors(x,l));; [0X
  [4X------------------------------------------------------------------[0X
  
  Having reached the ultimate choice of basis, we recreate the fixed vector [10Xv[0m.
  
  [4X---------------------------  Example  ----------------------------[0X
    [4Xgap> x := egens[1]-egens[1]^0;;[0X
    [4Xgap> nsx := NullspaceMat(x);;[0X
    [4Xgap> y := nsx * (egens[2]-egens[2]^0);;[0X
    [4Xgap> nsy := NullspaceMat(y);;[0X
    [4Xgap> v := nsy[1]*nsx;; [0X
  [4X------------------------------------------------------------------[0X
  
  Finally  we  need  small  faithful permutation representations of the helper
  subgroups.
  
  [4X---------------------------  Example  ----------------------------[0X
    [4Xgap> mgens32 := List(mgens,x->ExtractSubMatrix(x,[1..32],[1..32]));[0X
    [4X[ <cmat 32x32 over GF(2,1)>, <cmat 32x32 over GF(2,1)> ][0X
    [4Xgap> S := StabilizerChain(Group(mgens32),rec(TryShortOrbit := 10));[0X
    [4X...[0X
    [4X<stabchain size=95040 orblen=3960 layer=1 SchreierDepth=7>[0X
    [4X <stabchain size=24 orblen=24 layer=2 SchreierDepth=4>[0X
    [4Xgap> p := Group(ActionOnOrbit(S!.orb,mgens32));[0X
    [4X<permutation group with 2 generators>[0X
    [4Xgap> i := SmallerDegreePermutationRepresentation(p);;[0X
    [4Xgap> pp := Group(List(GeneratorsOfGroup(p),x->ImageElm(i,x)));[0X
    [4X<permutation group with 2 generators>[0X
    [4Xgap> m12 := MathieuGroup(12);;[0X
    [4Xgap> i := IsomorphismGroups(pp,m12);;[0X
    [4Xgap> mpermgens := List(GeneratorsOfGroup(pp),x->ImageElm(i,x));[0X
    [4X[ (5,7)(6,11)(8,9)(10,12), (1,10,3)(2,11,12)(4,5,6)(7,9,8) ][0X
    [4Xgap> lpermgens := ResultOfStraightLineProgram(slpm12tol211,mpermgens);[0X
    [4X[ (1,8)(2,5)(3,9)(4,7)(6,11)(10,12), (1,8,3)(2,7,12)(4,6,9)(5,11,10) ] [0X
  [4X------------------------------------------------------------------[0X
  
  We  could  just go on from here, however, sometimes it is useful to save all
  the created data to disk.
  
  [4X---------------------------  Example  ----------------------------[0X
    [4Xgap> f := IO_File("data.gp","w");;[0X
    [4Xgap> IO_Pickle(f,"seed");; [0X
    [4Xgap> IO_Pickle(f,v);; [0X
    [4Xgap> IO_Pickle(f,"generators");; [0X
    [4Xgap> IO_Pickle(f,bgens);; [0X
    [4Xgap> IO_Pickle(f,egens);; [0X
    [4Xgap> IO_Pickle(f,fgens);; [0X
    [4Xgap> IO_Pickle(f,mgens);; [0X
    [4Xgap> IO_Pickle(f,lgens);;[0X
    [4Xgap> IO_Pickle(f,"permutations");; [0X
    [4Xgap> IO_Pickle(f,mpermgens);; [0X
    [4Xgap> IO_Pickle(f,lpermgens);;[0X
    [4Xgap> IO_Close(f);; [0X
  [4X------------------------------------------------------------------[0X
  
  This can be loaded again, in particular into a new [5XGAP[0m session, as follows.
  
  [4X---------------------------  Example  ----------------------------[0X
    [4Xgap> LoadPackage("orb");;[0X
    [4X...[0X
    [4Xgap> LoadPackage("cvec");;[0X
    [4X...[0X
    [4Xgap> f := IO_File("data.gp");[0X
    [4X<file fd=4 rbufsize=65536 rpos=1 rdata=0>[0X
    [4Xgap> IO_Unpickle(f);[0X
    [4X"seed"[0X
    [4Xgap> v:=IO_Unpickle(f);;[0X
    [4Xgap> IO_Unpickle(f);[0X
    [4X"generators"[0X
    [4Xgap> bgens := IO_Unpickle(f);;[0X
    [4Xgap> egens := IO_Unpickle(f);;[0X
    [4Xgap> fgens := IO_Unpickle(f);;[0X
    [4Xgap> mgens := IO_Unpickle(f);;[0X
    [4Xgap> lgens := IO_Unpickle(f);;[0X
    [4Xgap> IO_Unpickle(f);[0X
    [4X"permutations"[0X
    [4Xgap> mpermgens := IO_Unpickle(f);;[0X
    [4Xgap> lpermgens := IO_Unpickle(f);;[0X
    [4Xgap> IO_Close(f);; [0X
  [4X------------------------------------------------------------------[0X
  
  Now we are prepared to actually run the orbit enumeration. Note that for the
  following  memory  estimates we assume that we are running things on a 64bit
  machine.  On a 32bit machine the overhead is smaller. We expect that all the
  vectors  in  the smaller quotient of dimension 20 will enumerated; needing 3
  bytes  per  vector  for  the actual data which results in 40 bytes including
  overhead, this amounts to 40 * 2^20 approx 42 MB of memory space. Since 2^32
  approx  4.3  *  10^9  is  less  than  [B: E], we also expect that the larger
  quotient  of  dimension 32 will be enumerated completely, by L_2(11)-orbits;
  needing  4  bytes  per  vector  for  the  actual  data resulting in 40 bytes
  including   overhead,   and   assuming  a  saving  factor  as  suggested  by
  [10XOrbitStatisticOnVectorSpace[0m  yields  an estimated memory requirement of 40 *
  2^32  *  1/598  approx  287  MB.  For the large B-orbit, being enumerated by
  M_{12}-orbits, we similarly get an estimated memory requirement of 584 * [B:
  E] * 1/93060 approx 85 MB.
  
  [4X---------------------------  Example  ----------------------------[0X
    [4Xgap> setup := OrbitBySuborbitBootstrapForVectors([0X
    [4X>             [lgens,mgens,bgens],[lpermgens,mpermgens,[(),()]],[0X
    [4X>             [660,95040,4154781481226426191177580544000000],[20,32],rec());[0X
    [4X#I  Calculating stabilizer chain for whole group...[0X
    [4X#I  Trying smaller degree permutation representation for U2...[0X
    [4X#I  Trying smaller degree permutation representation for U1...[0X
    [4X#I  Enumerating permutation base images of U_1...[0X
    [4X#I  Looking for U1-coset-recognising U2-orbit in factor space...[0X
    [4X#I  OrbitBySuborbit found 100% of a U2-orbit of size 95 040[0X
    [4X#I  Found 144 suborbits (need 144)[0X
    [4X<setup for an orbit-by-suborbit enumeration, k=2>[0X
    [4Xgap> o := OrbitBySuborbitKnownSize(setup,v,3,3,2,51,13571955000);[0X
    [4X#I  OrbitBySuborbit found 100% of a U2-orbit of size 1[0X
    [4X#I  OrbitBySuborbit found 100% of a U2-orbit of size 23 760[0X
    [4X...[0X
    [4X#I  OrbitBySuborbit found 51% of a U3-orbit of size 13 571 955 000[0X
    [4X<orbit-by-suborbit size=13571955000 stabsize=306129918735099415756800 ([0X
    [4X51%) saving factor=56404> [0X
  [4X------------------------------------------------------------------[0X
  
  Indeed the saving factor actually achieved is smaller than the best possible
  estimate given above, but it still has the same order of magnitude.
  
