>> << Ndx Usr Pri Phr Dic Rel Voc !: wd Help Dictionary

2. Alphabet and Numbers

       (a. {~ j +/ i.26) ; (j +/ i.6) ; (j=: a. i. 'aA') ; ($ a.)
    +--------------------------+--------------------+-----+---+
    |abcdefghijklmnopqrstuvwxyz|97 98 99 100 101 102|97 65|256|
    |ABCDEFGHIJKLMNOPQRSTUVWXYZ|65 66 67  68  69  70|     |   |
    +--------------------------+--------------------+-----+---+

       1 2 3{ t=: 8 32$a.         NB. The major alphabet
     !"#$%&'()*+,-./0123456789:;<=>?
    @ABCDEFGHIJKLMNOPQRSTUVWXYZ[\]^_
    `abcdefghijklmnopqrstuvwxyz{|}~

The table`t` arranges the alphabet in eight rows, but its complete display would look odd because of the effects of various control characters such as the carriage return. A boxed display`<t` is more readable because spaces are substituted for them.

       i. 2 5                     NB. Table of integers
    0 1 2 3 4
    5 6 7 8 9

       r=: 0j1 _1 0j_1 1          NB. Square roots of plus and minus 1
       + r                        NB. (Complex) conjugates
    0j_1 _1 0j1 1

       r * +r
    1 1 1 1

       r */ r                     NB. Multiplication table of roots of unity
      _1 0j_1    1  0j1
    0j_1    1  0j1   _1
       1  0j1   _1 0j_1
     0j1   _1 0j_1    1

       ! 45x                      NB. “x” denotes extended precision
    119622220865480194561963161495657715064383733760000000000

>> << Ndx Usr Pri Phr Dic Rel Voc !: wd Help Dictionary