>> << Ndx Usr Pri Phr Dic Rel Voc !: wd Help Dictionary

Do | ". 1 _ _ | Numbers

`".y` executes the sentence`y` .`` If the execution results in a noun, the result of`".y` is that noun; if the execution result is a verb, adverb, or conjunction, the result of`".y` is an empty vector.

`x".y` converts character array`y` into numbers. The shape of the result is`(}:$y),(1=n)}.n` where`n` is the maximum number of numbers in any row.`x` is a scalar number used to replace illegal numbers and to pad narrow rows. In the conversion, the normal rules for numeric constants are relaxed as follows:

- the negative sign can be`-` or`_`
- commas within numbers are ignored
- fractions need not have a digit 0 before the decimal point
- a number may be preceded by a`+` sign; the exponent of a number in exponential format may be preceded by a`+` sign

For example:

       ". s=: '5 * a=: 3 + i. 6'
    15 20 25 30 35 40

       a
    3 4 5 6 7 8

       do=: ".
       do t=: '3 % 5'
    0.6
       do |. t
    1.66667
       $ do ''
    0

       ]program=: 'a=: 2^3' ,: '5*a'
    a=: 2^3
    5*a

       do program
    8 40

       do 'sum=: +/'

       sum 1 2 3 4
    10

       s ; _999". s=: '1 2 3','-4 .5',:'bad 3,141'
    +---------+--------------+
    |1 2 3    |   1    2    3|
    |-4 .5    |  _4  0.5 _999|
    |bad 3,141|_999 3141 _999|
    +---------+--------------+

>> << Ndx Usr Pri Phr Dic Rel Voc !: wd Help Dictionary