>> << Ndx Usr Pri Phr Dic Rel Voc !: wd Help Dictionary

Oblique | m/. u/. _ _ _ | Key

`u/.y` applies`u` to each of the oblique lines of a table`y` .`` For example:

       i.3 4
    0 1  2  3
    4 5  6  7
    8 9 10 11

       </. i.3 4
    +-+---+-----+-----+----+--+
    |0|1 4|2 5 8|3 6 9|7 10|11|
    +-+---+-----+-----+----+--+

In general,`u/.y` is the result of applying`u` to the oblique lines of`_2`-cells of`y` .`` If the rank of`y` is less than two,`y` is treated as the table`,.y` .
`m/.y` applies successive verbs from the gerund`m` to the oblique lines of `_2`-cells of`y`,`` extending`m` cyclically as required. Thus:

       <`(<@|.) /. i.3 4
    +-+---+-----+-----+----+--+
    |0|4 1|2 5 8|9 6 3|7 10|11|
    +-+---+-----+-----+----+--+

`x u/.y` ↔`(=x) u@# y` ,`` that is, items of`x` specify keys for corresponding items of`y` and`u` is applied to each collection of`y` having identical keys. For example:

       1 2 3 1 3 2 1 </. 'abcdefg'
    +---+--+--+
    |adg|bf|ce|
    +---+--+--+

`x m/.y` applies successive verbs from the gerund`m` to the collections of`y`,`` extending`m` cyclically as required.

The application of a function to diagonals of a table is commonly useful, as in correlation, in convolution, and in products of polynomial coefficients (or, equivalently, products of numbers in a fixed base). For example:

       t=: p */ q [ p=: 1 2 1 [ q=: 1 3 3 1

       t ; (+//.t) ; 1 1 &(+//.@(*/)) ^: (i.6) 1
    +-------+-------------+-------------+
    |1 3 3 1|1 5 10 10 5 1|1 0  0  0 0 0|
    |2 6 6 2|             |1 1  0  0 0 0|
    |1 3 3 1|             |1 2  1  0 0 0|
    |       |             |1 3  3  1 0 0|
    |       |             |1 4  6  4 1 0|
    |       |             |1 5 10 10 5 1|
    +-------+-------------+-------------+

       ((10#.p)*10#.q), 10 #. +//. p */ q
    161051 161051

Unlike polynomial coefficients, the diagonal sums of a multiplication table of digits should be “normalized” if any equal or exceed the radix.

>> << Ndx Usr Pri Phr Dic Rel Voc !: wd Help Dictionary