>> << Ndx Usr Pri Phr Dic Rel Voc !: wd Help Primer

# Link - dyad ;

The dyad `;` (link) makes it easy to create a list of boxed nouns.

       2 3 4 ; 4 7 9
    +-----------+
    ¦2 3 4¦4 7 9¦
    +-----------+

       'abc' ; 5 7 9
    +---------+
    ¦abc¦5 7 9¦
    +---------+

       (2 3 $ 'abcdef') ; (i. 3 4) ; 23
    +----------------+
    ¦abc¦0 1  2  3¦23¦
    ¦def¦4 5  6  7¦  ¦
    ¦   ¦8 9 10 11¦  ¦
    +----------------+

Look link up in the J Dictionary. Note that its dyad rank is `_ _` so it applies to its entire left and entire right argument. It always boxes its left argument, and its right argument is boxed only if not already boxed. Boxing its right argument only if not already boxed makes the following work:

       'abc' ; 'defg' ; 'hijkl'
    +--------------+
    ¦abc¦defg¦hijkl¦
    +--------------+

This is evaluated from right-to-left as:

       'abc' ; ('defg' ; 'hijkl')

So the right argument to the leftmost link is already boxed, and will not be boxed again. Boxed again? What would that look like?

       'abc' ; < 'defg' ; 'hijkl'
    +----------------+
    ¦abc¦+----------+¦
    ¦   ¦¦defg¦hijkl¦¦
    ¦   ¦+----------+¦
    +----------------+

Boxes can be nested!

>> << Ndx Usr Pri Phr Dic Rel Voc !: wd Help Primer