    // **************************************************************************
    //
    //                 Хвост глагольной конструкции
    //
    // **************************************************************************
    // --------- тайна сия велика есьмь Обсоятельство -------------
    @Перевод
    {
       @Структура  фраза_однородный_член = союз все_все ;
       @Структура  фраза_однородный_член = союз все_все ;
    }

    @Перевод
    {
       @Выбор      обстоятельство1 =
                   предлог_сущ
                   гр_наречия
                   but_do_глагол
                   фраза_that
                   фраза_whether
                   фраза_обстоятельство
                   фраза_однородный_член
                   ;
       @Выбор      обстоятельство1 =
                   предлог_сущ
                   гр_наречия
                   but_do_глагол
                   фраза_that
                   фраза_whether
                   фраза_обстоятельство
                   фраза_однородный_член
                   ;
    }

    @Перевод
    {
       @Выбор2     _пред_обстоятельство =
                   предлог_сущ
                   гр_наречия
                   фраза_обстоятельство
                   обстоятельство_пп
                   @00
                   ;
       @Выбор2     _пред_обстоятельство =
                   предлог_сущ
                   гр_наречия
                   фраза_обстоятельство
                   обстоятельство_пп
                   @00
                   ;
    }

    @Перевод
    {
       @Структура  обстоятельство2 = обстоятельство1 _обстоятельство ;
       @Структура  обстоятельство2 = обстоятельство1 _обстоятельство ;
    }

    @Перевод
    {
       @Выбор      _обстоятельство = обстоятельство2 рв_вопрос1 @00;
       @Выбор      _обстоятельство = обстоятельство2 рв_вопрос1 @00;
    }

    // --------- хвосты, которые лезут в модель дополнений
    // PP:@0[to]=PP(Д):@0[_]
    // PP:@0[for]=PP(Р):@0[для]
    @Перевод
    {
    // He cut his finger. = он режет его палец (test01)
       @Структура  хвост_1 = гр_сущ_а ;
       @Структура  хвост_1 = гр_сущ_а( %В ) ;
    }

    @Перевод
    {
    // They told me that I was too early. = они сказали мне, что я был слишком рано (test25)
       @Структура  хвост_2 = гр_сущ_а ;
       @Структура  хвост_2 = гр_сущ_а( %Д ) ;
    }

    @Перевод
    {
    // She said to him that... = она сказала ему, что... (test26)
       @Структура  хвост_3 = @0[to] гр_сущ_а ;
       @Структура  хвост_3 = гр_сущ_а( %Д ) ;
    }

    @Перевод
    {
    // We heard from Jones all. = мы услышали от Джона все (test38)
       @Структура  хвост_4 = предлог_сущ гр_сущ_а ;
       @Структура  хвост_4 = предлог_сущ гр_сущ_а( %В ) ;
    }

    @Перевод
    {
    // to search for manual pages. =
       @Структура  хвост_4а = предлог_сущ ;
       @Структура  хвост_4а = предлог_сущ ;
    }

    @Перевод
    {
    // You must write her a letter. = ты должен написать ей письмо (test40)
       @Структура  хвост_5 = гр_сущ_а гр_сущ_а ;
       @Структура  хвост_5 = гр_сущ_а( %Д ) гр_сущ_а( %В ) ;
    }

    @Перевод
    {
    // We appointed him manager =  мы назначили его менеджером (test16)
       @Структура  хвост_6 = гр_сущ_а гр_сущ_а ;
       @Структура  хвост_6 = гр_сущ_а( %В ) гр_сущ_а( %Т ) ;
    }

    // --------- хвосты, которые лезут в модель дополнений с трудом
    @Перевод
    {
    // I found the box empty. = я нашел этот ящик пустым (test15)
       @Структура  хвост_7 = гр_сущ_б гр_прил ;
       @Структура  хвост_7 =
                   гр_сущ_б( &Число, &Лицо, %В, &Род )
                   гр_прил( Род, %Н, %Т, Число )
                   ;
    }

    @Перевод
    {
    // ------- это вообще можно сделать способом распространять существительное ----
       @Структура  хвост_8 = гр_сущ_б глагол( &S1, %Form2 ) ;
       @Структура  хвост_8 =
                   гр_сущ_б( &Число, &Лицо, %В, &Род )
                   глагол( %Сов, %причастие, @0, @0, @0, Род, %Пассив, %В )
                   ;
    }

    // --------- хвосты, которые НЕ лезут в модель дополнений ----------
    @Перевод
    {
    // Do you think it odd that I should live by myself? (test07)
    // Ты думаешь это странно, что я живу один
       @Структура  хвост_21 = @0[it] гр_квази_наречия ;
       @Структура  хвост_21 = @0[что_это] гр_квази_наречия ;
    }

    @Перевод
    {
    // You wouldn't want there to be war. =
    // Вы не хотите, чтобы была другая война (test05)
       @Структура  хвост_22 = @0[there] @0[to] @0[be] _No гр_сущ_б ;
       @Структура  хвост_22 =
                   @0[чтобы]
                   _No
                   глагол[быть] ( %Сов, %глагол, @0, Число, %прошлое, Род, %Актив, @0 )
                   гр_сущ_б( &Число, &Л, %И, &Род )
                   ;
    }

    @Перевод
    {
    // They proved him to be wrong. = Они считали что он был виноват (test06)
       @Структура  хвост_23_1 = гр_сущ_б to_inf2( &S1 ) ;
       @Структура  хвост_23_1 =
                   @0[что] гр_сущ_б( &Ч, &Л, %И, &Р ) to_inf2( Число, Род ) ;
    }

    @Перевод
    {
    //  I sent Tom to buy some stamps. = я послал тома купить марки (test23)
       @Структура  хвост_23_2 = гр_сущ_в to_inf( &S1 ) ;
       @Структура  хвост_23_2 = гр_сущ_в( &Ч, %В, &Р ) to_inf( Ч, Р ) ;
    }

    @Перевод
    {
       @Структура  хвост_23_3 = гр_сущ_в to_inf( &S1 ) ;
       @Структура  хвост_23_3 = гр_сущ_в( &Ч, %В, &Р ) @0[чтобы] to_inf( Ч, Р ) ;
    }

    @Перевод
    {
    // I do not want anyone to know. = я не хочу чтобы кто-нибудь знал (test04)
       @Структура  хвост_23_4 = гр_сущ_б to_inf2( &S1 ) ;
       @Структура  хвост_23_4 = @0[чтобы] гр_сущ_б( &Ч, &Л, %И, &Р ) to_inf2( Ч, Р ) ;
    }

    @Перевод
    {
       @Выбор      хвост_а =
                   хвост_1
                   хвост_2
                   хвост_3
                   хвост_4
                   хвост_5
                   хвост_6
                   хвост_7
                   хвост_8
                   хвост_4а
                   хвост_21
                   хвост_22
                   хвост_23_1
                   хвост_23_2
                   хвост_23_3
                   хвост_23_4
                   @00
                   ;
       @Выбор      хвост_а =
                   хвост_1
                   хвост_2
                   хвост_3
                   хвост_4
                   хвост_5
                   хвост_6
                   хвост_7
                   хвост_8
                   хвост_4а
                   хвост_21
                   хвост_22
                   хвост_23_1
                   хвост_23_2
                   хвост_23_3
                   хвост_23_4
                   @00
                   ;
    }

    @Перевод
    {
       @Структура  хвост = хвост_а _обстоятельство ;
       @Структура  хвост = хвост_а _обстоятельство ;
    }