| Online Eiffel Documentation

EiffelStudio

# EiffelBase, Iteration

The classes of the Iteration cluster encapsulate control structures representing common traversal operations.

# Iterators and Agents

The recent introduction of the agents mechanism in Eiffel offers an attractive alternative to theIterator cluster of EiffelBase.

# The Notion of iterator

Let us first explore the role of iterators in the architecture of a system.

## Iterating over data structures

Client software that uses data structures of a certain type, for example lists or trees, often needs to traverse a data structure of that type in a predetermined order so as to apply a certain action to all the items of the structure, or to all items that satisfy a certain criterion. Such a systematic traversal is called an iteration.
Cases of iteration can be found in almost any system. Here are a few typical examples:

- A text processing system may maintain a list of paragraphs. In response to a user command, such as a request to resize the column width, the system will iterate over the entire list so as to update all paragraphs.
- A business system may maintain a list of customers. If the company decides that a special promotion will target all customers satisfying a certain criterion (for example all customers that have bought at least one product over the past six months), the system will iterate over the list, generating a mailing for every list item that satisfies the criterion.
- An interactive development environment for a programming language may maintain a syntax tree. In response to a program change, the system will traverse the tree to determine what nodes are affected by the change and update them.

These examples illustrate the general properties of iteration. An iteration involves a data structure of a known general type and a particular ordering of the structure's items. For some structures, more than one ordering will be available; for example a tree iteration may use preorder, postorder or breadth-first (as defined below). The iteration involves an operation, sayitem_action, to be applied to the selected items. It may also involve a boolean-valued query, sayitem_test, applicable to candidate items. Finally, it involves a certain policy, usually based onitem_test, as to which items should be subjected to item_action. Typical example policies are:

- Applyitem_action to all the items in the structure. (In this case item_test is not relevant).
- Applyitem_action to all items that satisfyitem_test.
- Applyitem_action to all items up to the first one that satisfiesitem_test.

The Iteration library provides many more, covering in particular all the standard control structures.

## Iterations and control structures

You can perform iterations without any special iteration classes. For example if customers is declared as

    customers: LIST [CUSTOMER]

then a classSPECIAL_PROMOTION of a text processing system may include in one of its routines a loop of the form

    	from
    		customers.start
    	until
    		customers.exhausted
    	loop
    		if recent_purchases.has (customers.item>) then
    			target_list.put (customers.item>)
    		end
    		customers.forth
    	end

Such schemes are quite common. But it is precisely because they occur frequently that it is useful to rely on library classes to handle them. One of the principal tasks of object-oriented software development is to identify recurring patterns and build reusable classes that encapsulate them, so that future developers will be able to rely on ready-made solutions.
The classes of the Iteration library address this need. Using them offers two benefits:

- You avoid writing loops, in which the definition of sub-components such as exit conditions, variants and invariants is often delicate or error-prone.
- You can more easily adapt the resulting features in descendant classes. The rest of this chapter shows how to obtain these benefits.

# Simple Examples

To get a first grasp of how one can work with the Iteration library, let us look at a typical iteration class and a typical iteration client.

## An example iterator routine

Here, given with its full implementation, is a typical Iteration library routine: the procedure until_do fromLINEAR_ITERATOR, the class defining iteration mechanisms on linear (sequential) structures.

    until_do is
    			-- Apply action to every item of target,
    			-- up to but excluding first one satisfying test.
    			-- (Apply to full list if no item satisfies test.)
    	require
    		traversable_exists: target /= Void
    	do
    		from
    			target.start
    		invariant
    			invariant_value
    		until
    			target.exhausted or else test
    		loop
    			action
    			target.forth
    		end
    	ensure
    		achieved: target.exhausted or else test
    		invariant_satisfied: invariant_value
    	end

The precise form of the procedure in the class relies on a call to another procedure, until_continue, and on inherited assertions. Here everything has been unfolded for illustration purposes.
This procedure will traverse the linear structure identified by target and apply the procedure calledaction on every item up to but excluding the first one satisfying test.
The class similarly offers do_all, do_while, do_for, do_if and other procedures representing the common control structures. It also includes functions such as exists and forall, corresponding to the usual quantifiers.
These iteration schemes depend on the procedure action, defining the action to be applied to successive elements, and on the function test, defining the boolean query to be applied to these elements. These features are declared in class ITERATOR (the highest-level deferred class of the Iteration library); here is test:

    test: BOOLEAN is
    		-- Test to be applied to item at current position in
    		-- target (default: value of item_test on item)
    	require
    		traversable_exists: target /= Void
    		not_off: not target.off
    	do
    		Result := item_test (target.item>)
    	ensure
    		not_off: not target.off
    	end

This indicates that the value of the boolean function test will be obtained by applying item_test to the item at the current position in the target structure. In ITERATOR, function item_test always return; descendant classes will redefine it so as to describe the desired test. Similarly, action is declared in class ITERATOR as a call to item_action. Descendants will redefine item_action, which as initially declared in ITERATOR is a procedure with a null body.
Going through item_action and item_test provides an extra degree of flexibility. Normally the action and test performed at each step apply to target . item>, so that it suffices to redefine the item_features. This is the case with all examples studied in this chapter. In a more general setting, however, you might need to redefine action and test themselves.

## An example use of iteration

Here now is an example illustrating the use of these mechanisms. The result will enable us to resize all the paragraphs of a text up to the first one that has been modified - as we might need to do, in a text processing system, to process an interactive user request. Assume a classTEXT that describes lists of paragraphs with certain additional features. The example will also assume a classPARAGRAPH with a procedureresize, and a boolean-valued attributemodified which indicates whether a paragraph has been modified. ClassTEXT inherits from LINKED_LIST and so is a descendant of LINEAR:

    class
    	TEXT

    inherit
    	LINKED_LIST [PARAGRAPH]
    		...
    feature
    		...
    end

In a class TEXT_PROCESSOR, you can use an iteration procedure to write a very simple procedureresize_ paragraphs that will resize all paragraphs up to but excluding the first one that has been modified:

    class
    	TEXT_PROCESSOR

    inherit
    	LINEAR_ITERATOR [PARAGRAPH]
    		redefine
    			item_action, item_test
    		end

    feature

    	resize_paragraphs (t: TEXT) is
    			-- Resize all the paragraphs of t up to but excluding
    			-- the first one that has been modified.
    		do
    			set (t)
    			until_do
    		end

    feature {NONE}

    	item_test (p PARAGRAPH): BOOLEAN is
    			-- Has p been modified?
    		do
    			Result := p.modified
    		end

    	item_action (p: PARAGRAPH) is
    			-- Resize p.
    		do
    			p.resize
    		end
    	...
    end

Thanks to the iteration mechanism, the procedureresize_paragraphs simply needs two procedure calls:

- To set its argument t as the iteration target, it uses procedureset. (This procedure is from class ITERATOR which passes it on to all iterator classes.)
- Then it simply calls until_do as defined above.

Procedure item_action is redefined to describe the operation to be performed on each successive element. Function item_test is redefined to describe the exit test.
As presented so far, the mechanism seems to limit every descendant of an iteration class to just one form of iteration. As shown later in this chapter, it is in fact easy to generalize the technique to allow a class to use an arbitrary number of iteration schemes.
What is interesting here is that the redefinitions of item_test and item_action take care of all the details. There is no need to write any loop or other control structure. We are at the very heart of the object-oriented method, enjoying the ability to encapsulate useful and common software schemes so that client developers will only need to fill in what is specific to their application.

# Using the Iteration Library

Let us now explore the classes of the Iteration library and the different ways of using them.

## Overview of the classes

There are only four Iteration classes, whose simple inheritance structure appeared at the beginning of this chapter.

- ITERATOR, a deferred class which describes the most general notion.
- LINEAR_ITERATOR, for iterating over linear structures and chains.
- TWO_WAY_CHAIN_ITERATOR, a repeated heir of LINEAR_ITERATOR, for iterating in either direction over a bilinear structure.
- CURSOR_TREE_ITERATOR, for iterating over trees.

As you will remember from thepresentation of the abstract overall taxonomy, the traversal hierarchy describes how data structures can be traversed; its most general class is TRAVERSABLE.
Each one of the iterator classes is paired with a traversal class (or two in one case):

ITERATOR | TRAVERSABLE
LINEAR_ITERATOR | LINEAR
TWO_WAY_CHAIN_ITERATOR | TWO_WAY_LIST
TWO_WAY_CHAIN_ITERATOR | TWO_WAY_LIST, TWO_WAY_CIRCULAR
CURSOR_TREE_ITERATOR | CURSOR_TREE

Each iterator class relies on the corresponding traversal class to provide the features for traversing the corresponding data structures, such as start, forth and exhausted for linear structures.
Of course the data structure class used in connection with a given iterator class does not need to be the iterator's exact correspondent as given by the above table; it may be any one of its descendants. For example you may use LINEAR_ITERATOR to iterate over data structures described not just by LINEAR but also by such descendants as LIST, LINKED_LIST, ARRAYED_LIST, or even TWO_WAY_LIST if you do not need the backward iteration features (for which you will have to use TWO_WAY_CHAIN_ITERATOR ).

## General iteration facilities

Class ITERATOR defines the features that apply to all forms of iterator.
An iterator will always apply to a certain target structure. The target is introduced in ITERATOR by the feature target: TRAVERSABLE [G]
Both the iterator classes and the traversal classes are generic, with a formal generic parameter G. The actual generic parameters will be matched through the choice of iteration target: for a generic derivation of the formSOME_ITERATOR [ACTUAL_TYPE] the target can only be of typeSOME_TRAVERSABLE [ACTUAL_TYPE] for the sameACTUAL_TYPE, whereSOME_TRAVERSABLE is the traversal class matchingSOME_ITERATOR according to the preceding table (LINEAR for LINEAR_ITERATORand so on), or one of its proper descendants.
Each of the proper descendants of ITERATOR redefines the type of target to the matching proper descendant of TRAVERSABLE, to cover more specific variants of the iteration target, For example in LINEAR_ITERATORthe feature is redefined to be of type LINEAR. ITERATOR also introduces the procedure for selecting a target:

    	set (s: like target) is
    			-- Make s the new target of iterations.
    		require
    			s /= Void
     		do
     			target := s
    		ensure
     			target = s
    			target /= Void
    		end

Next ITERATOR introduces the routines describing the elementary action and test that will be applied to items of the iteration targets:

    	action is
    			-- Action to be applied to item at current position in
    			-- target.
    			-- (default: item_action on item at current position.)
    			-- Note: for iterators to work properly, redefined
    			-- versions of this feature should not change the
    			-- traversable structure.
    		require
    			traversable_exists: target /= Void
    			not_off: not target.off
    			invariant_satisfied: invariant_value
    		do
    			item_action (target.item>)
    		ensure
    			not_off: not target.off
    			invariant_satisfied: invariant_value
    		end

    	test: BOOLEAN is
    			-- Test to be applied to item at current position in
    			-- target (default: value of item_test on item)
    		require
    			traversable_exists: target /= Void
    			not_off: not target.off
    		do
    			Result := item_test (target.item>)
    		ensure
    			not target.off
    		end

These routines rely on two others, item_action and item_test, which both take an argument of type G, the formal generic parameter. The reason, already noted above, is that in a vast majority of cases the iterated action and test solely depend, at each step of the traversal, on the item (of type G) at the current position. To define an iteration process, then, it suffices to redefine item_action and item_test in a descendant of the appropriate iteration class. Only in complex cases will it be necessary to redefine action and test themselves.
If you encounter such a case, note the caveat about action changing the target's structure. Understandably enough, an iterator that attempts to change the data structure while traversing it may engage in strange behavior. No such risk exists if you only redefine item_action, which may change the contents of items but not the structure itself.
Another feature introduced in ITERATOR is the query invariant_value, describing invariant properties that must be ensured at the beginning of any iteration and preserved by every iteration step. As declared in ITERATOR this query always returns true, but proper descendants can redefine it to describe more interesting invariant properties.
Finally, ITERATOR introduces in deferred form the general iteration routines applicable to all iteration variants. They include two queries corresponding to the quantifiers of first-order predicate calculus:

- for_all will return true if all items of the target structure satisfy test.
- exists will return true if at least one item satisfies test.

The other routines are commands which will traverse the target structure and apply action to items selected through test:

- do_all applies action to all items.
- do_if, to those items which satisfy test.
- until_do, to all items up to but excluding the first one that satisfies test.
- do_until, to all items up to and including the first one that satisfies test.
- while_do and do_while, to all items up to the first one that does not satisfy test. (This can also be achieved with until_do or do_until by choosing the opposite test.)

All these features, and most of the other iteration features introduced in proper descendants of ITERATOR and described next, have no argument. Information about the target of iteration comes from feature target, set by procedure set; information about what needs to be done for each item of the target structure comes from item_action and item_test.

## Linear and chain iteration

LINEAR_ITERATOR, an effective class, refines the iteration mechanisms for cases in which the target is a linear structure, such as a list in any implementation or a circular chain.
The class effects all the deferred features inherited from ITERATOR, taking advantage of the linear traversal mechanisms present in the corresponding traversal class, LINEAR. Here for example is the effecting of do_if:

    	do_if is
    			-- Apply action to every item of target satisfying
    			-- test.
    		do
    			from
    				target.start
    			invariant
    				invariant_value
    			until
    				target.exhausted
    			loop
    				if test then
    					action
    				end
    				forth
    			end
    		end

This routine text relies on features start, forth and exhausted which, together with off, have for convenience been carried over to LINEAR_ITERATOR from their counterparts in LINEAR, with feature declarations such as

    	off: BOOLEAN is
    			-- Is position of target off?
    		require
    			traversable_exists: target /= Void
    		do
    			Result := target.off
    		end

and similarly for the others.
In addition to effecting the general iteration features from ITERATOR, class LINEAR_ITERATOR introduces iteration features that apply to the specific case of linear structures:

- search ( b :BOOLEAN) moves the iteration to the first position satisfying test if b is true, or not satisfying test if b is false. This use of a boolean argument to switch between two opposite semantics is not part of the recommended style, and you will find few if any other examples in the Base libraries. Here, however, it was deemed preferable to the alternative, which would have involved four separate procedures (if together with search we consider continue_search discussed next).
- With a linear structure we can implement an iteration corresponding to the 'for' loop of traditional programming languages, defined by three integers: the starting position, the number of items to be traversed, and the step between consecutive items. This is provided by procedure do_for ( starting , number , step :INTEGER).
- Since with a linear target the iterator can advance the cursor step by step, the basic iteration operations are complemented by variants which pick up from the position reached by the last call: continue_until, until_continue, continue_while, while_continue, continue_search, continue_for.

## Two-way iteration

Class TWO_WAY_CHAIN_ITERATOR has all the features of LINEAR_ITERATOR, to which it adds features for iterating backward as well as forward.
The class introduces commands finish and back, applying the corresponding operations to the two-way target. It also has a backward variant for every iteration feature. The name of each such variant is the name of the forward feature followed by_back: do_all_back, until_do_back and so on.
An alternative design would have kept just one set of features and added two features: a command reverse to reverse the direction of future iteration operations, and a query backward to find out the direction currently in force.
Contrary to what one might at first imagine, class TWO_WAY_CHAIN_ITERATOR is extremely short and simple; its Feature clause only contains the declarations of two features, finish and back.
The trick is to use repeated inheritance. TWO_WAY_CHAIN_ITERATOR inherits twice from LINEAR_ITERATOR; the first inheritance branch yields the forward iteration features, the second yields those for backward iteration. There is no need for any explicit declaration or redeclaration of iteration features. Here is the entire class text that yields this result:

    class
    	TWO_WAY_CHAIN_ITERATOR [G]

    inherit
    	LINEAR_ITERATOR [G]
    		redefine
    			target
    		select
    			start,
    			forth,
    			do_all,
    			until_do,
    			do_until,
    			do_if,
    			do_for,
    			search,
    			forall,
    			exists,
    			until_continue,
    			continue_until,
    			continue_for,
    			continue_search
    		end

    	LINEAR_ITERATOR [G]
    		rename
    			start as finish,
    			forth as back,
    			do_all as do_all_back,
    			until_do as until_do_back,
    			do_until as do_until_back,
    			do_if as do_if_back,
    			do_for as do_for_back,
    			search as search_back,
    			forall as forall_back,
    			exists as exists_back,
    			until_continue as until_continue_back,
    			continue_until as continue_until_back,
    			continue_for as continue_for_back,
    			continue_search as continue_search_back
    		redefine
    			target
    		end

    feature -- Status report

    	target: BI_LINEAR [G]
    			-- The structure to which iteration features will
    			-- apply

    feature -- Cursor movement

    	finish is
    			-- Move cursor of target to last position.
    		do
    			target.finish
    		end

    	back is
    			-- Move cursor of target backward one position.
    		do
    			target.back
    		end
    end

This class provides a good example of the economy of expression that the full inheritance mechanism affords through the combination of renaming, redefinition, repeated inheritance rules and selection, without sacrificing clarity and maintainability.

## Tree iteration

Tree iterations, provided by class CURSOR_TREE_ITERATOR, work on trees of the cursor tree form; only with this form of tree are traversal operations possible. Three forms of iteration are provided: preorder, postorder and breadth-first. They correspond to the three traversal policies described in the discussion of trees. Here too it would seem that a rather lengthy class is needed, but repeated inheritance works wonders.
CURSOR_TREE_ITERATOR simply inherits three times from LINEAR_ITERATOR, renaming the features appropriately in each case:

- pre_do_all,pre_until and so on.
- post_do_all,post_until and so on.
- breadth_do_all,breadth_until and so on.

All it needs to do then is to redefine the type of target to be CURSOR_TREE [ G ] , and to redefine six features: the three renamed start (pre_start etc.) and the three forth (pre_ forth and so on). These seven redefinitions give us a full-fledged battery of tree iteration mechanisms.

# Building and Using Iterators

To conclude this discussion, let us now put together the various mechanisms studied so far, to see how authors of client software can use the Iteration library to perform possibly complex iterations on various data structures without ever writing a single loop or test. The basic ideas were sketched above but now we have all the elements for the full view.
An application class may use one of the iteration classes in either of two ways: as a descendant (single or repeated) or as a client. The descendant technique is extremely simple but less versatile.

## The single descendant technique

Assume an application classPROCESSOR that is a proper descendant of one of the effective iteration classes studied in this chapter. Then a routine ofPROCESSOR, sayiterate, may iterate a certain action over a data structure, subject to a certain test. First, classPROCESSOR must specify the action by redefining item_action and item_test (or, in the most general case, action and test). Then routine iterate must specify the target data structure through a call of the form set ( t ) where t represents the selected target data structure. The type of t must correspond tothe iteration class selected as ancestor of PROCESSOR: for LINEAR_ITERATORit must be a descendant of LINEAR (such as LINKED_LIST, ARRAYED_LIST, LINKED_CIRCULAR or any other list or circular chain classes); for TWO_WAY_CHAIN_ITERATOR it must be a descendant of BILINEAR such as TWO_WAY_LIST or TWO_WAY_CIRCULAR; for CURSOR_TREE_ITERATORit must be a descendant of CURSOR_TREE. In all cases the actual generic parameters of the iterator class and ofthe data structure class must be compatible. Then the iteration proper is obtained simply by calling the appropriate procedure, without any qualification or arguments, for example: do_ if
It is hard to imagine a simpler scheme: no loops, no initialization, no arguments. Feature item_action may need to rely on some variable values. Because it does not take any argument, such values will have to be treated as attributes, with the correspondingset_... procedures to set and change their values. This also applies to the two schemes set next.
The single descendant technique has one drawback: it provides the iterating class,PROCESSOR, with only one set of iteration particulars. This limitation does not affect the number of targets: you may use as many targets as you wish, as long as they are of compatible types, by calling a routine such as iterate several times, or calling several such routines, each call being preceded by a call to set to define a new target. The limitation also does not affect the iterating scheme: one iteration could use do_if, the next do_all and so on. But it does require the action and test to be the same in all cases.
The next two techniques will remove this limitation.

## Using repeated inheritance

One way to obtain several iteration schemes is a simple extension to the single descendant technique. You can use repeated inheritance to provide two or more variants. We have in fact already encountered the technique when studying how to derive TWO_WAY_CHAIN_ITERATOR and CURSOR_TREE_ITERATORfrom LINEAR_ITERATOR. The general pattern, applied here to just two iteration schemes but easily generalized to more, is straightforward:

    class
    	DUAL_PROCESSOR

    inherit
    	LINEAR_ITERATOR [SOME_TYPE]
    		rename
    			item_action as action1,
    			item_test as test1,
    			do_if as do_if1,
    		redefine
    			action1, test1
    		select
    			action1, test1
    		end

    	LINEAR_ITERATOR [SOME_TYPE]
    		rename
    			item_action as action2,
    			item_test as test2,
    			do_if as do_if2,
    		redefine
    			action2, test2
    		end

    feature

    	action1 is
    			-- Action for the first scheme
    		do
    			...
    		end

    	test1: BOOLEAN is
    			-- Test for the first scheme
    		do
    			...
    		end

    	action2 is
    			-- Action for the second scheme
    		do
    			...
    		end

    	test2: BOOLEAN is
    			-- Test for the second scheme
    		do
    			...
    		end

    	iterate1 is
    			-- Execute iteration of first kind.
    		do
    			set (...)
    			do_if1
    		end

    	iterate2 is
    			-- Execute iteration of second kind.
    		do
    			set (...)
    			do_if2
    		end

    		...
    end

The repeated inheritance machinery takes care of the rest.

## Using explicit iterator objects

To obtain maximum flexibility, classes that need iteration facilities should be clients rather than descendants of the iteration classes. The resulting scheme is completely dynamic: to perform iterations you use iterator objects as discussed earlier.
The following example illustrates the technique. Consider a deferred classFIGURE describing the notion of graphical figure, with many effective descendants (POLYGON,CIRCLE and so on). It is useful to defineCOMPLEX_FIGURE, describing figures that are recursively composed of sub-figures. This is a remarkable example of multiple inheritance:

    class
    	COMPLEX_FIGURE

    inherit
    	FIGURE,
    	LINKED_LIST [FIGURE]

    feature
    	...
    end

In the feature clause we want to provide the appropriate effectings for the deferred features of classFIGURE:display,hide,translate and all other basic figure operations.
We can use loops for that purpose, for example

    	display is
    			-- Recursively display all components of the complex
    			-- figure
    		do
    			from
    				start
    			until
    				exhausted
    			loop
    				item.display
    				forth
    			end
    		end

Although acceptable and even elegant, this scheme will cause significant duplication: all theFIGURE features - not justdisplay but alsohide,rotate,move and others - will have the same structure, with a loop. We can use iterators to avoid this duplication. The repeated inheritance technique would work, but given the large number ofFIGURE features the amount of repeated inheritance that would be needed seems unwieldy. It is also not very desirable to have to change the inheritance structure of the system just to add a new feature toFIGURE. The more dynamic approach using iterator objects seems preferable.
To implement this approach, define a class for iterating on complex figures:

    class
    	COMPLEX_FIGURE_ITERATOR

    inherit
    	LINEAR_ITERATOR
    		redefine
    			target
    		end

    create
    	set

    feature

    	target: COMPLEX_FIGURE

    end

Then for each operation to be iterated define a small class. For example:

    class
    	FIGURE_DISPLAYER

    inherit
    	COMPLEX_FIGURE_ITERATOR
    		redefine
    			item_action
    		end

    create
    	set

    feature

    	item_action (f: FIGURE) is
    			-- Action to be applied to each figure: display
    			-- it.
    		do
    			f.display
    		end
    end

Similarly, you may defineFIGURE_HIDER,FIGURE_MOVER and others. Then the features ofCOMPLEX_FIGURE are written almost trivially, without any explicit loops; for example:

    	display is
    			-- Recursively display all components of the complex
    			-- figure
    		local
    			disp: FIGURE_DISPLAYER
    		do
    			create disp.set (Current)
    			disp.do_all
    		end

and similarly for all the others.
Note the use ofset as creation procedure, which is more convenient than requiring the clients first to create an iterator object and then to callset. This is also safer, since withset as a creation procedure the client cannot forget to initialize the target. (If a classC has a creation clause, the creation instruction create C.)