// This drops several enemies when the passage is blocked
// The water must have been filled at least once for it to function
IfTimeOut
  tmpargument = 20
  SetTime


  IfStateIs0
    // Check if the water has been filled
    GetWaterLevel
    tmpx = tmpargument
    tmpy = 600
    IfXIsMoreThanY
      // The water has been filled
      tmpargument = 1
      SetState
      // Make music for the drop...
      tmpargument = 22
      tmpdistance = 5
      tmpturn = IGCOMBAT
      SetMusicPassage
  Else
    tmpargument = passage
    SetTargetToWhoeverIsInPassage
      IfTargetIsAlive
        tmpargument = 0
        SendMessage


        // The drop sound
        tmpargument = 0
        tmpdistance = 11025
        PlaySound


        // Spawn the characters
        GetContent                 // The specific model slot


        // Character 1
        tmpx = selfx
        tmpy = selfy
        tmpdistance = rand & 255 + 800
        tmpturn = rand
        SpawnExactCharacterXYZ

        // Character 2
        tmpx = selfx - 256
        tmpdistance = rand & 255 + 800
        tmpturn = rand
        SpawnExactCharacterXYZ

        // Character 3
        tmpx = selfx + 256
        tmpdistance = rand & 255 + 800
        tmpturn = rand
        SpawnExactCharacterXYZ

        // Don't hang around
        GoPoof


End					// All done
