//This function makes an item fall to the floor when spawned
IfSpawned
  tmpargument = ACTIONJB
  DoAction
  KeepAction
IfDropped				// Make it lie on floor
  KeepAction
IfGrabbed				// Tell them what they've won, Johnny!
  SetTargetToWhoeverIsHolding
  IfTargetIsAPlayer
    tmpargument = 0
    SendMessageNear
IfHitGround
  tmpargument = 0
  tmpdistance = rand & 2047 + 8000
  PlaySound
  tmpargument = ACTIONDB
  DoAction
IfHeld			//Hide in hand
  tmpargument = 1
  SetState
Else
  tmpargument = 0
  SetState

//Spell stuff
IfUsed
  SetTargetToWhoeverIsHolding
  tmpargument = [GOOD]
  IfTargetHasSpecialID				//Need divine spell skill
    GetContent
    tmpx = tmpargument
    tmpy = 768					//Don't overcharge
    IfXIsLessThanY
      tmpy = targetmanaflow			//Enough spell power?
      IfYIsMoreThanX
        tmpargument = 8				//Mana cost
        CostTargetMana
          GetContent				//Increase the charge
          tmpargument = tmpargument + 8		//Casting Time
          SetContent
        
    // Spawn particles around target
    SetTargetToNearestFriend
    tmpx = targetdistance
    tmpy = 375
    IfXIsMoreThanY			//No target in range, select caster
      SetTargetToWhoeverIsHolding
    tmpx = targetx
    tmpy = targety
    tmpdistance = targetz
    tmpargument = 1
    SpawnExactParticle
    tmpargument = RED			//Icon sparkles
    SparkleIcon

Else
  GetContent
  tmpx = tmpargument
  tmpy = 750
  IfXIsMoreThanY		//Enough power to activate?
    tmpx = targetx
    tmpy = targety
    tmpdistance = targetz
    tmpargument = 2
    SpawnExactParticle
    SetOldTarget			//Remember the spell target
    SetTargetToWhoeverIsHolding
    SetOwnerToTarget			//Make the caster sustain the spell
    SetTargetToOldTarget		//Retarget the spell target
    EnchantTarget		//Do the enchant
    tmpargument = 100		//Set cooldown time
    SetReloadTime
    tmpargument = 3
    SendMessageNear		//Tell what happened
    tmpargument = 1
    tmpdistance = rand & 6000 + 11000
    PlaySound
  Else				
    GetContent
    tmpx = tmpargument
    tmpy = 0
    IfXIsMoreThanY		//Only if there was a charge
      tmpargument = 1
      SendMessageNear		//Tell it didn't work
      tmpargument = 2
      tmpdistance = rand & 6000 + 11000
      PlaySound
  tmpargument = 0
  SetContent			//Reset counter
  UnsparkleIcon

  //Award xp and stuff for daring to do it
  IfNameIsKnown
    DoNothing
  Else
    tmpargument = 20
    tmpdistance = EXPDARE
    GiveExperienceToTarget
    MakeNameKnown
    MakeUsageKnown

// Put the little mana ball on the
// character's hand
GetContent
tmpx = tmpargument
tmpy = 0
IfXIsMoreThanY
  tmpturn = tmpargument < 4 + 3000
  tmpdistance = SPAWNORIGIN
  tmpargument = 0
  SpawnAttachedSizedParticle

End					// All done
