;
;* ProComm for Windows Version 2.1
;* INFORMATION EXCHANGE Receive/Send EDI Only Script
;
PROC MAIN
;
;* SERVICE MANAGER LOGON SEQUENCE
;
PAUSE 2
termmsg "`r`n"
termmsg "CONNECT TO IGN SUCCESSFUL`r`n"
TRANSMIT "+LOGON EXPASYNC ACCOUNT(ACCT1) USERID(USERID1) PASSWORD(PASSW1);^M"
termmsg "`r`n"
termmsg "+LOGON SENT TO SERVICE MANAGER`r`n"
WAITFOR "+READY" 45
;
IF FAILURE
  GOTO FAIL02
ENDIF
;
;
;* INFORMATION EXCHANGE LOGON SEQUENCE
;
PAUSE 2
termmsg "`r`n"
termmsg "LOGON THROUGH SERVICE MANAGER SUCCESSFUL`r`n"
TRANSMIT "+CONNECT ACCOUNT(IEACCT) USERID(IEUSER) PASSWORD(IEPASSW);^M"
termmsg "`r`n"
termmsg "+CONNECT SENT TO INFORMATION EXCHANGE`r`n"
WAITFOR "+READY" 45
;
IF FAILURE
  GOTO FAIL02A
ENDIF
termmsg "`r`n"
termmsg "+CONNECT ACCEPTED`r`n"
;
;* RECEIVE EDI SEQUENCE
;
termmsg "`r`n"
termmsg "ATTEMPTING FILE TRANSFER ** FROM IE **`r`n"
TRANSMIT "+SELECT EDIRCV(Y);^M"
termmsg "`r`n"
termmsg "+SELECT RECEIVE EDI ONLY SENT TO IE`r`n"
;
WAITFOR "+SELECT DOCUMENTS FOLLOW" 45
PAUSE 3
;
IF FAILURE
  GOTO FAIL05
ENDIF
;
;* FILE TRANSFER FROM IE
;
termmsg "`r`n"
termmsg "SELECT ACCEPTED`r`n"
termmsg "`r`n"
termmsg "FILE TRANSFER ** FROM IE ** IN PROGRESS`r`n"
GETFILE XMODEM "C:\PROWIN2\EDIFILES.REC"
WAITFOR "+READY" 45
;
IF FAILURE
  GOTO FAIL06
ENDIF
;
;* FILE TRANSFER FROM IE SUCCESSFUL
;
termmsg "`r`n"
termmsg "FILE TRANSFER ** FROM IE ** SUCCESSFUL`r`n"
;
;
;* SEND SEQUENCE - EDI
;
SENDEDI:
termmsg "`r`n"
termmsg "ATTEMPTING FILE TRANSFER ** TO IE **`r`n"
TRANSMIT "+SEND;^M"
termmsg "`r`n"
termmsg "+SEND SENT ** TO IE **`r`n"
WAITFOR "+READY" 45
;
IF FAILURE
  GOTO FAIL03
ENDIF
;
;* FILE TRANSFER TO INFORMATION EXCHANGE
;
termmsg "`r`n"
termmsg "+SEND ACCEPTED -- UPLOAD IN PROGRESS`r`n"
SENDFILE XMODEM "C:\PROWIN2\EDIFILE.SND"
   while $XFERSTATUS
   endwhile
;
IF SUCCESS
  GOTO GOODSEND
ENDIF
;
termmsg "`r`n"
termmsg "** ERROR 03A **`r`n"
GOTO FAIL03A
;
GOODSEND:
termmsg "`r`n"
termmsg "FILE TRANSFER ** TO IE ** SUCCESSFUL`r`n"
;
TRANSMIT "+EOF;^M"
termmsg "`r`n"
termmsg "+EOF SENT TO IE`r`n"
WAITFOR "+READY" 45
;
IF FAILURE
  GOTO FAIL04
ENDIF
;
termmsg "`r`n"
termmsg "+EOF ACCEPTED`r`n"
;
;* LOGOFF SEQUENCE
;
LOGOFF:
termmsg "`r`n"
termmsg "LOGOFF IN PROGRESS`r`n"
TRANSMIT "+LOGOFF;^M"
termmsg "`r`n"
termmsg "+LOGOFF SENT TO INFORMATION EXCHANGE`r`n"
WAITFOR "+SESSION TERMINATED NORMALLY" 45
;
IF FAILURE
  GOTO FAIL07
ENDIF
;
termmsg "`r`n"
termmsg "+LOGOFF ACCEPTED`r`n"
;
END:
HANGUP
termmsg "`r`n"
termmsg "********************************************`r`n"
termmsg "      DISCONNECT FROM IE IN PROGRESS        `r`n"
termmsg "********************************************`r`n"
EXIT
;
;* ERROR MESSAGES
;
;
FAIL02:
termmsg "`r`n"
termmsg "** ERROR 02 **`r`n"
termmsg "`r`n"
termmsg "LOGON TO SERVICE MANAGER FAILED`r`n"
termmsg "PLEASE TRY AGAIN LATER`r`n"
GOTO END
;
FAIL02A:
termmsg "`r`n"
termmsg "** ERROR 02A **`r`n"
termmsg "`r`n"
termmsg "LOGON TO INFORMATION EXCHANGE FAILED`r`n"
termmsg "PLEASE TRY AGAIN LATER`r`n"
GOTO END
;
FAIL03:
termmsg "`r`n"
termmsg "** ERROR 03 **`r`n"
termmsg "`r`n"
termmsg "INVALID RESPONSE TO +SEND`r`n"
FAIL03A:
termmsg "`r`n"
termmsg "** ERROR 03A **`r`n"
termmsg "`r`n"
termmsg "FILE TRANSFER ** TO INFORMATION EXCHANGE ** FAILED`r`n"
GOTO LOGOFF
;
FAIL04:
termmsg "`r`n"
termmsg "** ERROR 04 **`r`n"
termmsg "`r`n"
termmsg "INVALID RESPONSE TO +EOF`r`n"
termmsg "FILE TRANSFER ** TO INFORMATION EXCHANGE ** FAILED`r`n"
GOTO LOGOFF
;
;
FAIL05:
termmsg "`r`n"
termmsg "** ERROR 05 **`r`n"
termmsg "`r`n"
termmsg "INVALID RESPONSE TO +SELECT`r`n"
termmsg "OR`r`n"
termmsg "NO EDI DOCUMENTS TO RECEIVE`r`n"
GOTO SENDEDI
;
FAIL06:
termmsg "`r`n"
termmsg "** ERROR 06 **`r`n"
termmsg "`r`n"
termmsg "+READY NOT RECEIVED FROM INFORMATION EXCHANGE`r`n"
termmsg "FILE TRANSFER ** TO INFORMATION EXCHANGE ** FAILED`r`n"
GOTO SENDEDI
;
;
FAIL07:
termmsg "`r`n"
termmsg "** ERROR 07 **`r`n"
termmsg "`r`n"
termmsg "INVALID RESPONSE TO +LOGOFF`r`n"
TRANSMIT "+LOGOFF;^M"
termmsg "`r`n"
termmsg "+LOGOFF SENT TO INFORMATION EXCHANGE -- SECOND ATTEMPT`r`n"
WAITFOR "+SESSION TERMINATED NORMALLY" 45
;
IF FAILURE
  termmsg "`r`n"
  termmsg "INVALID RESPONSE TO +LOGOFF -- SECOND ATTEMPT`r`n"
  GOTO END
ENDIF
;
termmsg "`r`n"
termmsg "+LOGOFF ACCEPTED`r`n"
GOTO END
;
;* END OF IE SCRIPT
;
ENDPROC